Subject: A mathematical check of LINET study........
Date: Tue, 25 Nov 1997 103342 -0600 (CST)
From: "Roy L. Beavers" <rbeavers@mail.llion.org>
To: emfguru@hotmail.com
--------------------------------------------------
Hi everybody:
Ed Maxey has furnished the following study.....
Only a few of you will want to do the math that he offers, but I hope
some of you will check it out. I know that some of you have already
applied your formulas to the Linet study (NCI study) with different
results than she announced.
Thanks, Ed! I expect two or three of our mathematical people will
want to pursue your suggestion......
Guru will soon be "forcing" a discussion of the "scientific"
value of the "TWA" (time weighted average) assumption..... It is
_designed_ to eliminate the ***exposure conditions that are most likely to
result in the most biological activity.***
[Guru says: In NO way, does the TWA assumption reflect actual "real
world" conditions. That's where the biological harm is actually
occurring..... Those real world conditions are of magnetic AND electric
fields that are the ***antithesis*** of the "smooth" time-weighted-average
***magnetic field only*** which has been the basis for most of the EMF
research to date. Those real world conditions are full of "pulses" and
"spikes" and "peaks" and "valleys." In a word, they are "intermittent" in
their character and effect. They are not "smooth" ... but are "dirty"
with transients and harmonics that (particularly when fed by electric
storms) expose the victim to the very opposite of the kind of exposure
that the TWA assumption presumes. For at least two years, now, some (few)
experimenters have realized this basic flaw in our research and have
clamored for a new direction to be taken. With but a few exceptions
-- like Charles Graham whom I have already mentioned to you -- that new
direction did not appear at San Diego!!!]
Perhaps the most remarkable thing about the TWA assumption is that: in
SPITE of its unrealistic and "unscientific" premise ... it is still
providing some modest results that show biological effect ... as appeared
(however grudgingly) in the Linet study and as demonstrated by Ed Maxey
below........
The real question is -- of course -- what more would we learn if we were
conducting our research under "real world" conditions or at least
"real world" assumptions????
This becomes particularly important when a number of studies using the
"magnetic field" TWA assumption are lumped together in a "meta analysis"
thus compounding the errors and deficiencies of the basic studies!!!!!
[Much more will be said about this in the future!!!!!]
Ed Maxey has provided some interesting "food for thought" below.....
Cheerio........
Roy Beavers (EMFguru)
rbeavers@llion.org..............http://www.feb.se/EMF-L/EMF-L.html
................................It is better to light a single candle ...
than to curse the darkness...............................................
DO YOU KNOW ANYONE WHO SHOULD BE ADDED TO THIS LIST??????
---------- Forwarded message ----------
Date: Tue, 25 Nov 1997 09:13:55 -0600 (CST)
From: Edward Maxey
To: rbeavers@mail.llion.org
Subject: ODDS.TXT
BASIC ANSWERS
by
Ed Naxey
The print out read, "The odds are 125,000 to one against 267 or
less HEADS when a basket of 624 coins is overturned." This was
GWBasic's answer when asked to set up trials of 624 random numbers
and then tally odds and evens in a million trials. Why are these
odds of interest?
Martha S. Linet etal. (RESIDENTIAL EXPOSURE TO MAGNETIC FIELDS AND
ACUTE LYMPHOBLASTIC LEUKEMIA IN CHILDREN) found "little evidence
that living in homes characterized by high measured time-weighted
average magnetic-field levels ... increases the risk of ALL in
children (N Engl J Med 1997;337:1-7.)." This report found that
there were 624 cases of acute lymphoblastic leukemia (ALL) in a
matched analysis. Only 267 of these had a residential
electromagnetic field exposures of under 0.065 æT (microTesla). It
seemed unlikely that chance alone would have been at play when so
few cases occurred in those residences with the lowest category of
exposure.
If the median residential EMF exposure in the United States were
known one could predict that chance alone would distribute 50% of
ALL cases on each side of the median value. This follows the
WEBSTER'S COLLEGIATE DICTIONARY definition; "Designating a point so
chosen in a series that half of the individuals in the series are
on one side of it, and half on the other."
The median residential EMF has been recognized by law. Judge
Michael Galvin (Decision 93-11-013 November 2, 1993, BEFORE THE
PUBLIC UTILITIES COMMISSION OF THE STATE OF CALIFORNIA) noted
"...the 0.35 milligauss median United States residential EMF level
generated by electric power facilities...." This value equates to
0.035 æT, about half of the 0.065 æT in the Linet paper. Judge
Galvin also noted that high fields may come from individual
appliances. The greatest offenders were hair dryers and electric
shavers. Few children sleep within a meter of blowing hair dryers
or buzzing shavers.
Judge Galvin additionally stated,
"The most often found source of magnetic fields in residential
and commercial property is the grounding system. The
grounding system includes water pipes, television cables, gas
pipelines, and other metallic paths that are grounded."
Many children are exposed to such fields. Parents can turn off
electric household appliances. They can not turn off EMFs from the
grounding system.
The Linet paper does not depict 0.065 æT as being higher than the
national median residential electromagnetic field exposure. Even
so, 0.065 æT was treated as the median in this computer program.
If the actual median were to be lower than 0.065 æT the odds of
acute ALL being linked to power line EMFs would be even greater
than 125,000 to one.
Here is the program in case you would like to have your computer
confirm these odds. Those with scanners may simply scan the
program into their computers. ANSWERS.BAS is suggested as a name.
The command line would then be:
GWBasic ANSWERS
and then press the enter key.
10 E1 = 312: O1 = 312' REM E1 gets lowest EVEN & O1 gets lowest ODD count
20 M = .5' REM M = Mid point; determines if number is ODD or EVEN
30 C=267' REM record any hits at or below 267
40 C1 = 265' REM Cutoff point minus 2 for array coverage
50 DEFDBL T' REM All "T" variables are double precision
60 TT =1:TE =1000000!' Rem counting 1 to 1,000,000
70 P$="**###,###,###,###,###":P1$="###,###"
80 P2$ = " to one against 267 or less being"
90 P3$= "HEADS when a basket of 624 coins is overturned."
100 DIM OS(94)' REM array holds individual ODDS & EVENS trials sums
110 CLS
120 PRINT "Trial number"TT" Evens - Odds ="TEVEN-TODD'REM show tally
130 FOR V = 1 TO 624 ' REM Flip 624 pennies for heads or tails
140 RANDOMIZE TIMER
150 IF RND < M THEN E = E + 1 ELSE O = O +1' REM Count evens and odds
160 NEXT V
170 IF E < E1 THEN E1 = E ' REM Find lowest even value in 1,000,000 trials
180 IF O < O1 THEN O1 = O ' REM Find lowest odd value in 1,000,000 trials
190 IF E =< C THEN E2 = E2 + 1 'REM Find number of even 267 or lower hits
200 IF O =< C THEN O2 = O2 + 1 'REM Find number of odd 267 or lower hits
210 OS(E-C1)=OS(E-C1)+1 ' REM Tally hits in each distribution category
220 TEVEN=TEVEN+E: TODD=TODD+O 'REM Tally all EVENS & all ODDS
230 TT = TT +1' REM Tally trials up to 1,000,000
240 E = 0: O = 0' REM Reset count variables to zero
250 IF TT < TE THEN GOTO 120' Rem loop until 1,000,000
260 REM Data determined. Now display it and save it on hard drive.
270 PRINT "There were "TT" trials."
280 OPEN "O", #1, "DISTRIB.TXT"'REM Save data using Print #1
290 PRINT #1,"There were "TT" trials."
300 PRINT "The EVENs totaled" USING P$;TEVEN
310 PRINT #1, "The EVENs totaled" USING P$;TEVEN
320 PRINT "The ODDs totaled " USING P$;TODD
330 PRINT #1 ,"The ODDs totaled " USING P$;TODD
340 PRINT "The minimum number of EVENs was"E1" and ODDs was "O1".
350 PRINT #1,"The minimum number for EVENs was"E1" and for ODDs was "O1".
360 PRINT "There were "E2" 267 or less EVEN hits and "O2" 267 or less ODD hits.
"
370 PRINT #1,"There were "E2" 267 or less EVEN hits and "O2" 267 or less ODD
hits."
380 PRINT "The odds are "USING P1$;TE/E2;:PRINT P2$:PRINT P3$
390 PRINT #1,"The odds are "USING P1$;TE/E2;:PRINT #1,P2$:PRINT #1,P3$
400 FOR V=0 TO 94: TF=TF+OS(V):NEXT V 'REM Tally the array as a check
410 PRINT "Total odd and even trials ="TF
420 PRINT #1,"Total odd and even trials ="TF
430 FOR V = 0 TO 94: 'REM Now print array to screen and disk
440 PRINT C1+V"="OS(V);
450 PRINT #1,C1+V"="OS(V);
460 IF V>0 AND (V/6)=INT(V/6) THEN PRINT
470 IF V>0 AND (V/6)=INT(V/6) THEN PRINT #1,
480 NEXT V
490 CLOSE #1
May BASIC's ANSWERS favor you.
Archive provided courtesy of WaveGuide, http://www.wave-guide.org
Reprinted with permission of Roy Beavers, http://www.feb.se/EMF-L/EMF-L.html